m103ex-3-10.html

Applications of Derivatives

Thomas/Finney Section 3.1, page 195

Problem 10

Find the maximum and minimum of for x in the interval

To find absolute extrema on closed intervals, check (a) where the derivative is 0, (b) where it fails to exist, and (c) at the endpoints:

> y:=4-x^2;

> dy:=diff(y,x);

> solve(dy=0,x);

The derivative exists for all x, and so we have to check the interior critical point x=0 as well as the endpoints x=-3 and x=1:

> [-3,subs(x=-3,y)],[0,subs(x=0,y)],[1,subs(x=1,y)];

We see that the minimum is -5 (at x=-3) and the maximum is 4 (at x=0).

Section 3.2, page 203

Problem 10

Let , for x in (0,1), and for x in [1, 2]. For what value(s) of , , and does satisfy tyhe hypotheses of the mean value theirem on the interval [0, 2]?

We need to choose a, m and b so that the function

> f:=piecewise(x=0,3,0<x and x<1,-x^2+3*x+a,1<=x and x<=2,m*x+b);

satisfies the hypotheses of the mean-value theorem on [0,2]. So it has to be continuous on the closed interval [0,2] (in particular at x=0 and x=1), and differentiable on the open interval (0,2) (in particular at x=1). So we solve three equations for three unknowns:

> solve({3=limit(-x^2+3*x+a,x=0,right),limit(-x^2+3*x+a,x=1,left)=limit(m*x+b,x=1,right),limit(diff(-x^2+3*x+a,x),x=1,left)=limit(diff(m*x+b,x),x=1,right)},{a,m,b});

> f:=subs(%,f);

This function should be continuous on [0,2] and differentiable on (0,2) -- let's see:

> plot(f,x=0..2,color=blue,thickness=2);

Section 3.3, page 208, Problem 21

Let .

(a) Find the intervals in which this is increasing or decreasing

(b) Identify the function's local extreme values, if any, saying where they are taken on.

Start by defining the function and its derivative:

> g:=x*sqrt(8-x^2);

> dg:=diff(g,x);

Of course, the domain of this function is where , i.e., for x between and .

Let's see where the derivative is positive and negative:

> solve(dg>0,x);

> solve(dg<0,x);

So the function is increasing when x is between -2 and 2, and decreasing to the left of -2 and to the right of 2. We calculate the critical values:

> simplify(subs(x=-2,g)),simplify(subs(x=2,g));

So the min point of the graph is at [-2,-4] and the max point is at [2,4]. These are absolute, since g is zero at the endpoints of the domain.

Now let's plot:

> plot(g,x=-2*sqrt(2)..2*sqrt(2),color=blue,thickness=2);

Section 3.4, page 217, Problem 21

Graph , including the coordinates of extreme points and inflection points.

We use calculus to make sure we have all the "interesting" points in our Maple plot:

> y:=x^5-5*x^4;

> solve(y=0,x);

> solve(diff(y,x)=0,x);

> solve(diff(y,x$2)=0,x);

Since y is a polynomial, we don't have to worry about any asymptotes. We need only

plot on an interval that contains all of x=0,3,4,5. To get an idea of the range on the y-axis, we'll substitute our "interesting" x-values into the function:

> subs(x=0,y),subs(x=3,y),subs(x=4,y),subs(x=5,y);

So we have to include a pretty big y range:

> plot(y,x=-4..7,-350..100,color=blue,thickness=2);

Section 3.5, page 230, Problem 101

Graph on the three intervals [-9, 9], [-90, 90], [-900, 900].

The graph on [-9, 9] should be good. That on [-90, 90] should show that something is happening near the origin, but be inconclusive, while the graph on [-900, 900] will almost look like (why?).

First we'll do the three graphs:

> y:=-(x^3-2)/(x^2+1);

> plot(y,x=-9..9,color=blue,thickness=2);

> plot(y,x=-90..90,color=blue,thickness=2);

You can see a very tiny kink in the graph at the origin.

> plot(y,x=-900..900,color=blue,thickness=2);

Now it just looks like the line y=-x. This is because:

> simplify(y+x);

> limit(y+x,x=infinity),limit(y+x,x=-infinity);

So the line y=-x is an oblique asymptote for the graph, and once you subtract the "dominant" -x from y, you get a function that goes rapidly to 0 as x gets large.

Section 3.6, page 242, Problem 30

A wall 8 feet high stands 27 feet from the larger wall of a building. A straight beam goes from the ground to the top of the 8 foot wall and extends to touch the wall of the building. Find the length of the shortest such beam.

Let x be the length of the beam, let h be the height on the building's wall where the beam touches, and let s be the distance from the little wall where the other end of the beam touches the ground. Then we want to minimize x (or, what is the same, ), where we have the following relationships between x, s and h:

> eqn1:=x=sqrt(h^2+(27+s)^2); eqn2:=h/8=(s+27)/s;

The second equation is the "constraint", and the first provides our "objective function". So we solve the second for h in terms of s, and then substitute into the first:

> eqn1:=subs(h=solve(eqn2,h),eqn1);

Now we can take the derivative and set it equal to 0:

> solve(diff(rhs(eqn1),s)=0,s);

We certainly don't want an imaginary root! So the minimum must occur when s=12 feet. We can substitute this into the first equation to see what x should be:

> simplify(subs(s=12,eqn1));

So the shortest beam that reaches is feet long.

Problem 56

You operate a tour service that offers the following rates:

a) $200 per person if 50 people (the minimum number to book the tour) go on the tour.

b) For each additional person (up to a maximum of 80 people total), everyone's charge is reduced by $2.

It costs $6000 (a fixed cost) plus $32 per person to conduct the tour. How many people does it take to maximize your profit?

From the information given in the problem we have the following formulas, where x is the number of people who are on the tour.

> cost:=6000+32*x;

Given that at least 50 people go on the tour, we have the following formula for revenue.

> revenue:=x*(200-2*(x-50));

> profit:=revenue-cost;

To maximize profit, we find where its derivative (also known as the marginal profit) is equal to zero, and then we must check that this is in fact a maximum.

> mp:=diff(profit,x);

> solve(mp=0);

The critical point of the profit function is 67 people. Since the second derivative of profit is -4 (we don't need Maple to tell us that!), this must be a maximum for the profit. And the profit is:

> subs(x=67,profit);